データ取得シート その3

　つづき

　恐々テーブルを付けてみたけど、速度は落ちなかった。これで完璧だ。

　率ベースにも直した。

　しかし、分割の有った銘柄で動かしてみると、途中　SUB Yahoo分割修正株価(ByVal rounded As Boolean)　で止まった。それで、僕には難しいので、訳も分らずとりあえず、’印をそのSUB全体に付け、動かしてみると動いた。（勝手なことをして申し訳ありません。）

ところが、へたれさんより、またファイルが送られてきた。それでSUB Yahoo分割修正株価(ByVal rounded As Boolean)　の意味が解った。修正後終値*を利用して4本値が修正してくれるのだ。全ての株価が連続する。これによって高値安値を使うProgure02にも使えるようになった。

　　　　　　　　　　　

　でも10年間の検証は大変だ。9000番台の銘柄から検証を始めたのだけど、ITバブルの時にどうしても合わしてしまうので、今最近にはそのパラメータでは合わないような気がする。

　10年間の間には何処かで山場があって10年間で良い成績を出そうとするならなば、どうしてもその山場にパラメータを合わせないといけない。そしてその後底での長い持合ではなかなか成績が上がらない、長いドローダウンの時期が続くのである。

　山場では上げと下げで両方取れるから良い成績を上げられるのだが。（誰でもか

　いや、案外それが出来ないのである。

　　　　　　　　　　*

　　　　　　　　　　*

　そうこうしているとまた、ファイルが送られてきた。今度はVBAから最適化のテーブルを作ったり、削除するようにコントロールボタンがちょうど良いところに付いているではないか。

　テーブルがあれば凄く重たくなるのだけど、必要でないときはボタン一つで消せて、必要なときだけボタン一つで呼び出せるのだ。

　これで、データ取得に掛かる時間や他の作業部分でも1/2短縮できる。

　（これも、今まで検証作業をした事のない者には分からないことだが、僕からすれば非常に助かるのである。）

　送られてきたファイルにはみずほ8411が検証されていました。もうこれ以上僕が手を加えることも既になくなったように感じた。（新しいアイデアがあれば別ですが。）

　　　　　　　　********

検証結果　　　　　　（　通常の移動平均と比較してみます　）

8411　みずほFG

検証期間　　　　2003/3/12　～　2008/3/4

　　　　　　　　　　　　通常　　　　　　　 　idou20

損益合計          1718600                 1310900

トレード数             313                      188

勝率                    42.8%                    54.3%

PF                       1.93                     2.66

損益レシオ           2.58                     2.24

平均利益            26610                   20607

平均損失          -10320                   -9198

最大利益           136000                 161000

最大損失           -52000                 -28000

MDD                                            -81000

MDD率                                          14.3%

連勝                                                 6

連敗                                                 9

　という結果が出ました。パラメータは上の図を見てください。勝率と利益は比例しないことが分かります。移動平均をそのまま使った場合どうしても勝率は45％程度になります。idouの特徴はその勝率を10％程度上げるところにあります。

　（最大利益 ）対（最大損失）をみれば５倍以上損益レシオも　2.20以上で損小利大の取引をしていることになります。

　ただし、この結果は8411の一番良い時期を取り上げたものです。持合のときは利益を上げることは出来ません。

　つづく

データ取得シート その2

　つづき

　これを、検証シートに合体するのだけど、このデータ取得シートに式をつけた方が手っ取り早い。

　へたれさんの場合、VBAで全ての内容を消去してからデータを取り込み、VBAからすべての式をコピーしています。それはエクセルと言うより90％VBAです。

　僕のようなVBA初心者（にわかプログラマー）にはちょっときついので,式の部分は50行まで予め入れておいて、毎回、時系列データと51以下の行は一旦消して再びVBAから50行の式を51行以下に最終行の一行手前までコピーするように改良しました。

　DDを求めるのにDD用の損益を求める式の初期値にその時の終値が入りますから、その部分だけは少し細工しなければなりません。

　VBAの教科書を引き出して作らなければいけなかったのですが。へたれさんのマクロの中にデータの最期の行番号を返す式がありました。

　これに終了を知らせるBeep音をつければ出来上がりです。

　　　　　　　　　********

　一つこれを作ってしまえば、どれにでも対応が出来る、改良するには少しの知識と感がいるけど1から作るのに比べたらはるかに楽だ。

　来週からこれを使い10年間の検証をしようと思う（どの期間でも検証可能）。

　　　　　　　　********

　評価欄（１行から２行）の式を２７００行まで対応するようにしなければならない。それと４１行の式が狂っていたので修正しないといけない。(le-4)ももしも式が狂っていれば直しておいて下さい。

　新たに１０年間のグラフを付けてみました。(le-4)にもグラフを付けてください。

　これは、5711マテリアルの１０年間です。

テーブルを付けてもっと最適化を完璧にしもっと良い数字を出したいのですが、速度が落ちるのが怖いです。

　それで、グラフの黄色線が資産曲線です。水色線がその最大値です。

　マイナスの折れ線がドローダウンです。

　最初の-192（MDD率61.5％）が大きいです。

　こんな感じで、これからも検証を続けようと思います。

  一つ大事なことを忘れていました。PSとLCが今は金額ベースになっていますが１０年の期間だと株価が１００円台のときもあれば１０００円台になる事もあるので、全て率ベースに変えなくてはなりません。今日はこの辺にして明日それを直していきます。

つづく

データ取得シート

　僕のやりたい事は、始めから決まっていた。フォームを使わないで、エクセルシートに銘柄コード、開始日、終了日を入力しボタンを一つ付けて、それを押せば、3分で10年分データ取得と言う物である。

　イメージだけは出来ていたのだ。

　しかし、10年分のデータ取得の問題点は株式分割が有る確率が高いと言うことだ。

　そこへ、へたれさんが完璧な形でヤフー時系列データ取得ファイルを送ってくださった。10年分のデータ取得に２分とかからなかった。

　早速、自分流に改良した。3行だけを書き換えれば出来た。ほかを直す必要はないし、深い部分は僕にはわからない。

　　　　　　　　　　

　後はこれを検証シートにつけて、最初のボタンだけで、検証シートの方へ式を壊すことなくデータがコピーされれば良いのである。

　あまりにもスムーズに動くものだから、ステータスバーを見ていないといつ終わったのか分らないぐらいだ。終了すればチャイムで知らせてくれるようにしよう。

　しかし、ぼくの仕事は雑いというか、詰めが甘いのである。80％出来たらまあ良いかといつもそうなってしまう。

　　　　　　　　　********

　本来ならメールでお礼の挨拶をヘたれさんにしなければならないのですが。この本文でどのようにヤフー時系列データ取得ファイルを自分用に改良したか、書いていきますので。それをもって挨拶と代えさせていただきます。

idou検証シートを整える

　前回の記事の通りに式を入れていくとファイルは次のようになります。

「le-3.xls」をダウンロード

　この状態ではパラメータが離れた所にあるので、それをまとめて、評価欄もまとめてその上でグラフをつけます。少しでも検証作業がスムーズに出来るようにします。

エクセルの練習のために上のファイルを一旦保存し、その上でした記のように式を書き込んだ下さい

　　　　　　　　　　

　　BE列にパラメータの項目名を入れていきます。BF列にはその数値を入れます。

｛セルBE4｝・・・短期移動平均　｛セルBF4｝・・・5

｛セルK3｝・・・=$BF4       (セルBF4の値がセルK3に入ります。）

　　　　　　　　　　*

｛セルBE5｝・・・長期移動平均　｛セルBF5｝・・・11

｛セルAF3｝・・・=$BF5       (セルBF5の値がセルAF3に入ります。）　

　　　　　　　　　　*

｛セルBE6｝・・・PS　　　　　　　　｛セルBF6｝・・・-40

｛セルAC1｝・・・=$BF6      

　　　　　　　　　　*

｛セルBE7｝・・・LC　　　　　　　　｛セルBF7｝・・・-60

｛セルAC2｝・・・=$BF7      

　　　　　　　　　　*

｛セルBE8｝・・・PS　　　　　　　　｛セルBF8｝・・・-12

｛セルAN1｝・・・=$BF8      

　　　　　　　　　　*

｛セルBE9｝・・・LC　　　　　　　　｛セルBF9｝・・・0

｛セルAN2｝・・・=$BF9    

　これで、BF列の値を好きに変える事により結果が変わります。　

　ちょっと休憩。

　　　　　　　　********

　システムトレードで必要な物は

１．売買指示シート　              （idou20.xls)

2.　検証シート                       (le-4.xls)

3.　検証用データ取得シート

この三つです。

　一応データ取得の方法も過去ログに載せている。ただこれは少し難しい。VBAの知識が要るのだ。

　しかし、多少は簡単にすることも出来る。フォームを使わなくても、直接エクセルのセルに銘柄コード、期間をいれれば出来るのだ。

　無料でデータ取得シートを公開しているサイトってあるのだろうか

　なければ多少時間が掛かっても、自分で作るしかない。ここで大きく差が出るからだ。データ取得シートがなければ、長い期間の検証にデータ取得の部分に時間が掛かる。

　具体的に言えばヤフー時系列から１０年間のデータを取得する場合50ページ（２５００日分のデータ）をコピーペーストしなければならない。この場合３０分は掛かる。（しかし、思ったより早くできた。）

　だが、これで、１０銘柄の検証をすれば、データ取得だけで５時間以上はかかる。データ取得シートが有れば１銘柄３分で出来るから１０銘柄３０分だ。この違いは大きい。

　無料でデータ取得シートを公開しているサイトが有るか調べてみよう・・・・・・・

検証結果の一部

　サインを公開している以上、それらの銘柄に対する過去２年間ぐらいの成績も併せて見てもらうのが筋だと思います。

　今までの検証シートはデータの貼り付けに非常に時間が掛かっていました。そこで、P-100から１枚だけ新しいブックにコピーし、MDD,MDD率、連敗、連勝の項目を付け加えました。これは、今記事で書いているidouの検証への改良をそのままP-100に移しました。

　「le-4.xls」をダウンロード 　（これはそのidouです）

　すると、いままでの1/4の速度で検証が出来るようになりました。

　検証にあまりにも時間が掛かると、検証作業が億劫になり、そのため取引機会をなくすと言うことも起こりうります。　　　　　　　

　　　　　　　　********

　システムトレードには以下のような一連の作業が伴います。

　データ取得⇒検証⇒パラメータの決定⇒銘柄の選定⇒数量の割り当て⇒日々のデータ更新とその準備⇒取引の決断（自動でも手動でもどちらでも良い）

　取引の決断に至るまでこれらの作業は必要だし。毎日、日々のデータ更新とその準備の作業はいるのです。だから、これら一つ一つの作業は早いに越したことはありません。

　　　　　　　　********

　検証の結果

　それでこれがこの２年間の検証結果ファイルです。

　「kennsyou-02.xls」をダウンロード

後から気が付いたんだけど、新光証券とアイカが勝率45％で最も悪かった、だから連敗数もやはり7・6と多い。しかしどちらも損益レシオが2.5以上でMDD率と連敗数は比例しないようである。

　MDD率、連勝、連敗から見て良かったのは

　　　　　　　　　　　　MDD率　　連勝　　連敗

8186　ケーヨ　　　　　7.7％　　　　9　　　　4

5711　マテリアル　　　8.2％　　　　8　　　　5

9669　オークネット　　8.4％　　　　7　　　　4　

　僕にはまだMDD率がどれぐらいなら許されるのか解からないが15％ぐらいが妥当だろうか      連敗数は6まで見ないといけないだろう。

idouに連勝・連敗を求める式

　前回の記事で書いた式を入れればファイルは次のようになります。

「le-2.xls」をダウンロード

これに前と同じ様に、下に書いている式を入れてください。

　　　　　　　　　　

　これらの式はIF文を使うのですが前回の式より少し複雑になります。

　連勝の条件式

　BA列に連勝数を出す式を入れていきます。

　AS列には損益が入っています。

　考え方はこの様になります。

AS>0なら（勝ちの時）BAは１増えます。AS<0なら（負けの時）BAは0になります。AS=0ならBAは変わりません。

　これをIF文にします。

｛セルBA４｝・・・　=IF(AS4>0,BA5+1,IF(AS4<0,0,BA5))

　下へコピーしてください。

　連敗の条件式

　BB列に連敗数を出す式を入れていきます。（連勝の式とパターンは同じで不等式の向きを変えて、BAをBBに変えれば出来ます。）

｛セルBB４｝・・・　=IF(AS4<0,BB5+1,IF(AS4>0,0,BB5))

となります。このIF文の意味は自分で考えてみてください。

　下へコピーしてください。

　ちょっと休憩

　　　　　　　　　　

　思うに今回の企画は良かった。このIF文も基本的な文だし、BA5+1もプログラムの基礎の基礎だ、美しい条件式だ。

　　　　　　　　　　

　後は評価欄を作れば出来上がり

{セルBC1}・・・　連　勝　　{セルBD1}・・・MAX(BA4:BA507)

{セルBC2}・・・　連　敗　　{セルBD2}・・・MAX(BB4:BB507)

結果は５連勝と５連敗でした。

　おわり

idouにDD率を求める列を加える

検証用にidouの銘柄シート１枚を新しいエクセルブックを作りそれにコピーペイストをすれば良いのだが、idouを開いてみると凄く重たい。

　そこで、こちらでそのファイルを用意することにしました。

                      「le-1.xls」をダウンロード

　　　これを使い、実際にDD率を出す列を作っていきます。

　　　　　　　　　　*

　AS列の式を

=IF(AJ4<>"",AJ4,IF(AO4<>"",AO4,0))

　と変えて下にコピーします。空白のセルに０が入ります。もしも何も変わらなければツール（T)、オプション、計算方法、テーブル以外自動（T)にチェックを入れOKをクリックしてください。

　　　　　　　　　　*

　AW列に（期初株価+現在の利益）を入れます。

｛セルAW３｝・・・DD用利益

その一番下のセルに

｛セルAW507｝・・・=$E507

その上のセルに

｛セルAW50６｝・・・=AW507+AS506

これを｛セルAW４｝まで上にコピーします。

　　　　　　　　　　*

　AX列にはその時の最大値が入ります。

｛セルAX３｝・・・最大値

｛セルAX４｝・・・=IF(AW4>AX5,AW4,AX5)

これを下までコピーします。式の意味は（IF文としては基本的な文です。）

AW4>AX5　なら最大値が変わり　AW4　違うなら（AW4<AX5なら）変わらず　AX5

が｛セルAX４｝に入ります。

　目が疲れてきたので、ちょっと休憩

　　　　　　　　　　*

　AY列にドローダウンを入れます。

｛セルAY４｝・・・=AW4-AX4

　　　　　　　　　　*

　AZ列にDD率を入れます。

｛セルAZ４｝・・・=ABS(AY4/AX4）

セルの書式を％に変えます。ABSは絶対値を出す関数です。

　　　　　　　　********

その評価欄を１行２行に設けます

｛セルBA1｝・・・MDD　　｛セルBB1｝・・・=MIN(AY4:AY507)

｛セルBA2｝・・・MDD率　　｛セルBB2｝・・・=MAX(AZ4:AZ507)

　　　　　　　　　　　*

　MDD　-255　　　　MDD率　6.9％

と言う数字が出れば正解。なんか良さそうな数字だ

　idou20　も捨て堅いなぁー

次回　連敗数、連勝数

DD率の分母を考える。

　今までの僕の検証では、連敗数、連勝数、最大ドローダウン（MDD)、ドローダウン率はあまり見ていなかった。

　連敗数は勝率から大体のことは解かると思った。

　なぜMDDを取り上げていないかと言うと、ドローダウン率の定義が今もって自分には、はっきりしないからです。

　つまり、分母の部分が、

　・　カブロボコンテストの場合　（５０００万+最高利益）

　・　資産の最高額　　　　　　　　（元金+最高利益）

　・　個別株の検証の場合　　　　（期初株価+最高利益）

　・　最高利益　（たぶんこれは成り立たない。利益が０の時は無限大になるから）

元金をカブロぼのように決めていたなら、まだ他の人のシステムと比較もできるけど、個別株の検証では元金を１００万に設定するのか３００万に設定するのかで結果が変わってくる。

　個別株の検証の場合,分母が人によって代わるようでは比較にはならない。だから、まだまだ勉強不足なところわはあるけど、DD率の定義として

　個別株の検証の場合　分母に（期初株価+最高利益）を採用しようと思う。

　DD率の式

DD率＝（最高利益－現在利益）/（期初株価+最高利益）

となる。

つづく

次回　これをidouにくみ込む

ミスを見つけて

　売りシステムにミスが見つかりました。そこで応急処置を考えたのですが、売りシステムにミスが有ると言うことは、買いシステムにも同じミスが有ってもよいのに、買いシステムの方にはミスがありませんでした。

　と言うことは買いシステムを売りに変換した時にあることが抜けていたと言うことです。

　　　　　　　　*

　そのミスは

　売買サインで見つかりました。タイトなストップをかけた時、ストップ（4）が出た翌日に買戻しの（3）が出てしまいます。それだと2度買うことになってしまいます。

　応急処置ではいけない、これは買いシステムからの変更箇所の見落としです。

　　　　　　　　*

　調べ直し、改めて後ほど書きます。

多分、下の式でいけると思います。

売りの売買サイン

｛セルＸ14｝・・・=IF(V14="ストップ", IF(V15="",4,1), IF(AND(T14=0,OR(X15=1,X15=4)),2,IF(T14=2,IF(OR(X15=4,X15=0),0,2),IF(T14=0,0,IF(T14=3,IF(X15=4,1,3),1)))))

青い部分を変えました。

Ｐｒｏｇｒｅ02 簡易検証シート まとめ

　今回の簡易Ｐｒｏｇｒｅ02は逆張り1：1　検証シートに対応させるために作りました。内容は従来のＰｒｏｇｒｅ02とほぼ同じなのですが取引がサインの出た翌日寄り付きになっています。列位置も変わっています。資金の増減を比較するものではないので取引株数は出ません。手数料も引いていません。

　逆張り1：1　検証シート　と共通部分は

Ａ列からJ列、Ｙ列からＡＤ列、評価部分、テーブル、等高線グラフです。

この部分は６月２４日の　逆張り1：1　検証シート　その1　を見てください。

また　Ｐｒｏｇｒｅ02の詳しい内容は過去記事を見てください。だいたい最初の方に大事なことが書いてあると思います。

　今回はＰｒｏｇｒｅ02のＩ列からＸ列を書きます。

各項目は図を参照してください。

各セルの式を書いて行きますのでコピー/ペーストしてください。

｛セルＩ14｝・・・=MAX(ABS(C14-D14),ABS(C14-E15),ABS(D14-E15))

　　これはＴＲ（ボラティリティー）を求める式です。

｛セルJ13｝・・・パラメータ（j日）（17に固定）

｛セルJ14｝・・・=AVERAGE(I14:OFFSET(I14,$J$13-1,0))

　　ＴＲの平均を求める式です。（移動平均もこの式を使います）

｛セルＫ13｝・・・パラメータ（ｎ倍）（自由に変えてください）

　　今私はこの数を探しています。（0.1から7.0までの数）

｛セルＫ14｝・・・=$J14*$K$13

｛セルL13｝・・・パラメータ（ｍ倍）（自由に変えてください）

　　今私はこの数を探しています。（0.1から7.0までの数）

｛セルL14｝・・・=$J14*$L$13

｛セルＭ14｝・・・=Q14-K14

｛セルN14｝・・・=IF($E14<M14,"*","")

｛セルO14｝・・・=R14+L14

｛セルP14｝・・・=IF($E14>O14,"*","")

｛セルQ12｝・・・パラメータ（q日）(24に固定）

｛セルQ14｝・=MAX($C14:OFFSET($C14,$Q$12-1,0))

｛セルR12｝・・・パラメータ（r日）(30に固定）

｛セルR14｝・=MIN($D14:OFFSET($D14,$R$12-1,0))

｛セルS12｝・・・パラメータ（s日）(4に固定）

｛セルS14｝・=MAX($C14:OFFSET($C14,$S$12-1,0))

｛セルT14｝・・・=IF(OR(AND($N15="*",$N14=""),AND($P15="",$P14="*")),IF(OR(T15=1,T15=3),1,3),IF(OR(AND($P15="*",$P14=""),AND($N15="",$N14="*")),IF(OR(T15=0,T15=2),0,2),IF(T15=2,0,IF(T15=3,1,T15))))

　この長い条件式は当システムの心臓部分です、この式の説明は4月９日の記事　その３　売買サイン　を見てください。

｛セルＵ12｝・・・パラメータ（u％）(9.00%に固定）

｛セルＵ14｝・・・=IF(T14=1,IF(U15>TRUNC(S14-S14*$U$12),IF(U15="",TRUNC(S14-S14*$U$12),U15),TRUNC(S14-S14*$U$12)),"")

　トレーディングストップの条件式

｛セルV14｝・・・=IF(AND(T14=1,E14<=U14),"ストップ","")

｛セルX14｝・・・=IF(V14="ストップ", IF(V15="",4,0), IF(AND(T14=1,OR(X15=0,X15=4)),3,IF(T14=2,IF(OR(X15=4,X15=0),0,2),IF(T14=0,0,IF(T14=3,3,1)))))

　この式がＰｒｏｇｒｅ02の売買サインです。上の式にトレーディングストップを付けたものです。

　　　　　　　　　　*

　後は逆張り1：1　検証シート　と共通です。是非とも完成してください。

｛セルＫ13｝・｛セルＬ13｝の値を変えることによって結果が変わるはずです。

自分の監視銘柄に合った値（パラメータ）を探してください。銘柄によってかなり違いが出ます。本にはＬＣと資金管理.（ポジションサイズの管理）で儲かるように書いてありますが、銘柄選びもかなり重要であるといえます。

　次回　だめな銘柄　（いつもよい成績の銘柄しか書いていませんが、検証していてがっかりさせられる事もあるんですよ。）

逆張り1：1 検証シート その3

　つづき

　

売買サイン

｛セルＸ14｝・・・=IF(S14=4, IF(OR(X15=1,X15=3),4,0), IF(AND(Q14=1,OR(X15=0,X15=4)),3,IF(T14=2,IF(OR(X15=4,X15=0),0,2),IF(Q14=3,3,IF(Q14=1,1,0)))))

　建値

｛セルＹ14｝・・・=IF(X15=3,B14,IF(X15=0,"",Y15))

　落値

｛セルＺ14｝・・・=IF(X14=2,V15,IF(X15=4,B14,""))

　損益

｛セルＡＡ14｝・・・=IF(Z14="","",Z14-Y14)

　累計損益

｛セルＡＢ14｝・・・=IF(AA14="",AB15,AB15+AA14)

　利益合計

｛セルＡC14｝・・・=IF(AA14>0,AC15+AA14,AC15)

この式であっていると思うのですが、なぜかエラーがでます。それで応急措置で

　　　　　　　　　　=AB15-AD15

を入れて見ました。

　損失合計

｛セルＡＤ14｝・・・=IF(AA14<0,AD15+AA14,AD15)

　　　　　　　　　　*

システム評価   

｛セルＹ4｝・・・累計損益　｛セルＺ4｝・・・=$AB$14   

｛セルＹ6｝・勝率　｛セルＺ6｝・=$Z$8/($Z$8+$Z$10)

｛セルＹ8｝・・・勝ち　　　｛セルＹ10｝・・・負け

｛セルＺ8｝・・・=COUNTIF($AA$14:$AA$1001,">0")

｛セルＺ10｝・・・=COUNTIF($AA$14:$AA$1001,"<=0")

PF   　｛セルAB2｝・・・=ABS($AC$13/$AD$13)

損益レシオ　　｛セルＡＢ4｝・・・=ABS($AB$8/$AB$6)

平均損失　　　｛セルＡＢ6｝・・・=$AD$14/$Ｚ$10

平均利益　　　 ｛セルＡＢ8｝・・・=$AC$14/$Ｚ$8

以上　式は終わり

後は最適化のためのテーブルを作ります。最適化のし方は3/5の記事を見て下さい。

ただ、テーブルを作るとＰＣが凄く重たくなります。ツール（Ｔ）、オプション（Ｏ）、計算方法、手動（Ｍ）かテーブル以外自動（Ｔ）を選択してください。

とにかく検証作業に慣れるだけです。

次回は　売買サインの条件式の説明。

逆張り1：1 検証シート その2

　つづき

売り条件1　ロスカット　（4）

｛セルＳ14｝・・・=IF(Q14=1,IF(E14<U14,IF(U15="","",4),""),"")

売り条件2　利益確定　（2）

｛セルＴ14｝・・・=IF(Q14=1,IF(C14>V14,IF(T15=2,"",2),""),"")

ロスカットの値

｛セルU14｝・・・=IF(Q14=1,IF(Y14="","",Y14*(1-$U$13)),"")

目標値

｛セルV14｝・・・=IF(Q14=1,IF(Y14="","",Y14*(1+$V$13)),"")

　　　　　　　　　　*

｛セルU13｝・・・パラメータ（ストップ率）

｛セルＶ13｝・・・パラメータ（目標率）

つづく

逆張り1：1 検証シート その1

　今回の検証シートは上１０行を空けて作ります。

Ｊ列までは従来どおりです。

各項目は図を参照してください。

各セルの式を書いて行きますのでコピー/ペーストしてください。

｛セルＫ13｝・・・パラメータ（ｎ日）

｛セルＫ14｝・・・=AVERAGE(OFFSET(E14,,,$K$13))

式の説明

OFFSET関数　：　Ｅ14を基準にして０列$K$13行まで

｛セルＭ14｝・・・=(E14-K14)/K14

｛セルL14｝｛セルN14｝は今回使いません、内容は上の式と同じで、ＫをＬに変えて下さい。

｛セルＯ13｝・・・パラメータ（ｎ％以下）

｛セルＯ14｝・・・=IF(M14<$O$13*(-0.01),"*","")

｛セルＰ14｝は今回使いません、内容は上の式と同じで、ＭをＮに、ＯをＰに変えて下さい。

｛セルQ14｝・・・=IF(AND(O14="*",O15=""),IF(Q15=0,3,IF(T15=2,0,1)),IF(OR(Q15=1,Q15=3),IF(T15=2,0,1),0))

式の説明は後ほど。一度試しにコピーしてみてください。まだＴ列に式を入れてないので、０から３に変わった後１が続くと思います。

つづく

その9.評価 （ほとんど終わり）

　つづき

検証シート全体図（４／６の記事）３番目を参照してください。

　いよいよ最終段階です。

システムの評価

｛セルＡＸ１５｝・・・総損益　　　｛セルＡＹ１５｝・・・=AL$3-AP740

　(740は列の１番下の行番号)

｛セルＡＸ１7｝・・・総損失　　　｛セルＡＹ１7｝・・・=AT$3

｛セルＡＸ１9｝・・・総利益　　　｛セルＡＹ１9｝・・・=AR$3

｛セルＡＸ21｝・・・総トレード数　

｛セルＡＹ21｝・・・=COUNTIF(AQ$3:AQ740,"<>0")

｛セルＡＸ23｝・・・損失トレード数　

｛セルＡＹ23｝・・・=COUNTIF(AQ$3:AQ740,"<0")

｛セルＡＸ25｝・・・利益トレード数　

｛セルＡＹ25｝・・・=COUNTIF(AQ$3:AQ740,">0")

｛セルＡＸ27｝・・・勝率　

｛セルＡＹ27｝・・・=$AY$25/$AY$21      (書式を％にしてください）

｛セルＡＸ29｝・・・平均損益　　　｛セルＡＹ29｝・・・=$ＡＹ$15/$ＡＹ$21

｛セルＡＸ31｝・・・平均損失　　　｛セルＡＹ31｝・・・=$ＡＹ$17/$ＡＹ$23

｛セルＡＸ33｝・・・平均利益　　　｛セルＡＹ33｝・・・=$ＡＹ$19/$ＡＹ$25

｛セルＡＸ35｝・・・最大利益　　　｛セルＡＹ35｝・・・=MAX(AQ$3:AQ740)

｛セルＡＸ37｝・・・最大損失　　　｛セルＡＹ37｝・・・=MＩＮ(AQ$3:AQ740)

｛セルＡＸ39｝・・最大ドローダウン　｛セルＡＹ39｝・・=MＩＮ(AＪ$3:AＪ740)

｛セルＡＸ40｝・・・率　　　　　　　｛セルＡＹ40｝・・・=MＡＸ(AＶ$3:AＶ740)

｛セルＡＸ41｝・・・プロフィットファクター

｛セルＡＹ41｝・・・=ABS($AY$19/$AY$17)

｛セルＡＸ43｝・・・シャープレシオ

｛セルＡＹ43｝・・・=ABS($AY$15/$AY$39)

｛セルＡＸ45｝・・・損益レシオ

｛セルＡＹ45｝・・・=ABS($AY$33/$AY$31)

｛セルＡＸ47｝・・・期待値

｛セルＡＹ47｝・・・=($AY$33*$AY$27)+($AY$31*(1-$AY$27))

　　　　　　　　　　　　　**********

これぐらいにしておきます。

予定どおりＧＷ前に完成いたしました。これで最適化が行なえます。

最適化は　(３月２４日の記事）　テーブルを使って最適値を探す　を見てください。

データの取得は　VBAでデータ取得　その1～その6まで読んでください。

そして、出きれば検証用のシートとデータ取得用のシートを１つのブックにしてください。

データ取得用のシートで例えば１０００日分のデータを取得します。それを検証用のシートにコピー/ペーストしてください。（これができれば非常に時間の短縮になります）

検証用のシートの前半部分はまったく売買指示シート（Ｐｒｏｇｕｒｅ02）と同じです。この部分を別のブックにコピーし５銘柄（5シート）ぐらいのブックにしてください。この場合の毎日のデータ取得は　(３月２日の記事）　クエリを使ってデータ取得 　を見てください。（ＶＢＡを使う事もできます。ある意味　ＶBAでデータ取得　の応用で　１ページだけのデータ更新なのでこちらの方が簡単なんです。しかし、クエリは基本的な操作なので、この機会に是非とも収得してください。）

　今まで売買サインの出し方をしつこく提案してきましたが、これは私が独断で決めたルールで今後の成績にはまったく自信がありません。また幼稚でシステムと言うのが恥ずかしいぐらいです。このシートの前半部分を各自で工夫し自分にあった投資ルールを是非とも見つけてください。

　つづく　

その8．ドローダウンの計算

つづき

ドローダウンの計算

　検証シート全体図（４／６の記事）２番目を参照してください。　　　

｛セルＡＫ２｝・・・最大累計損益

｛セルＡＫ３｝・・・=IF(AL3>AK4, AL3, AK4)

｛セルＡＪ２｝・・・ドローダウン

｛セルＡＪ３｝・・・=AL3-AK3

　　　　　　　　　　　　　***************

損益の計算

｛セルＡＱ２｝・・・損益

｛セルＡＱ３｝・・・=IF(OR(AE3=2,AE3=4),AI3*AO3-$AN$1,0)

　　　　　　　　　　　　　***

｛セルＡＲ２｝・・・利益合計

｛セルＡＲ３｝・・・=IF(AQ3>0,AR4+AQ3,AR4)

｛セルＡＳ１｝・・・勝　　　　　｛セルＡＳ２｝・・・ＴＤ日数

｛セルＡＳ３｝・・・=IF(AND(OR(AE3=2,AE3=4),AQ3>0),AF3,"")

　　　　　　　　　　　　　***　

｛セルＡＴ２｝・・・損失合計

｛セルＡＴ３｝・・・=IF(AQ3<0,AT4+AQ3,AT4)

｛セルＡＵ１｝・・・負　　　　　｛セルＡＵ２｝・・・ＴＤ日数

｛セルＡＵ３｝・・・=IF(AND(OR(AE3=2,AE3=4),AQ3<0),AF3,"")

                            ***

｛セルＡV１｝・・・ドローダウン　　　　　｛セルＡV２｝・・・率

｛セルＡV１｝・・・=ABS(AJ3/AK3)

　これで検証シートの主な式が出来あがりました。これから実際にこれらをコピー／ペーストし上手く行くかテストしてみます。

　最後に各セルの書式を整えてください（ＡＶ列は％、マイナスは赤表示とか）

　次回は　評価結果の出力

その7．損益曲線の元の式

つづき

　検証シート全体図（４／６の記事）２番目を参照してください。　　　

｛セルＡM２｝・・・株   

｛セルＡＭ３｝・・・=IF(AE3=1,E3*AO3,IF(OR(AE3=2,AE3=4),AH3*AO3,AG3*AO3))

　この式は株の評価額

　売買サイン（1）の時　　終値*株数

　売買サイン（２）か（４）の時　落値*株数

　売買サイン（０）か（３）の時　建値*株数　（売買サイン（０）の時は建値のセルが０なのでこのセルは０になります。）

　　　　　　　　　　　　*************

｛セルＡＮ２｝・・・ＣＰ

｛セルＡＮ３｝・・・=IF(AE3=1,AN4,IF(OR(AE3=2,AE3=4),AN4-$AY$5,AP4-AM3))

　この式は現金の計算

　売買サイン（1）の時　前日と変わらず

　売買サイン（２）か（４）の時　前日の現金－手数料（$AY$5）　（株を売ったので現金が増えますが、その結果は次の日になります）

　売買サイン（０）か（３）の時　前日の資金－株の評価額

　これをそのままコピー／ペーストしてください。

ＡＪ列からＡＬ列がまだ入ってないので途中から０に成りますよね。

　　　*************

｛セルＡＬ２｝・・・累計損益

｛セルＡＬ３｝・・・=AM3+AN3

これをそのままコピー／ペーストしてください。

下までコピー／ペーストすれば全ての値が出ると思います。

ＡＬ列を折れ線グラフにしたものが損益曲線です。

つづく

その6・買い付け株数,資金

つづき

いよいよ検証用の部分に入ります。

　検証シート全体図（４／６の記事）２番目を参照してください。

｛セルＡＯ１｝・・・買付可能　　　　｛セルＡＯ２｝・・・株数

｛セルＡＯ３｝・・・=IF(OR(AE3=1,AE3=2,AE3=4),AO4,IF(AE3=0,0,IF(TRUNC((($AY$12*AP4)/J3)/$AY$4)*$AY$4*AG3>AP4,TRUNC(AP4/(AG3*$AY$4))*$AY$4,TRUNC(($AY$12*AP4/J3)/$AY$4)*$AY$4)))

この式の説明は（４月３日の記事）ポジションサイズのとり方と式の訂正

http://gyutetu.cocolog-nifty.com/blog/2007/04/post_1.html

を見てください。

売買サイン（0）の時は　０

売買サイン（３）の時に　買い付け可能株数が表示されます。（今ある資金を越えないように、またTRUNC関数を使い単位株数以下の端数を切捨てするように。してあります。）

売買サイン（1）（2）（4）の時は　前日の株数と同じ

　ＡＰ列の最初（私の場合｛セルＡＰ740｝３年前）に初期資金1,000,000または（=$AY$3)を入力しておいてください。

　ここからは実際にこのシートが作れるか自分もしながら記事を書いていきます。色々と忘れている事もありますので,思い出しながらの作業になります。

この時点ではまだＡＯ列は０ですよね。

｛セルＡＰ２｝・・・資金

｛セルＡＰ３｝・・・=IF(OR(AE3=2,AE3=4),AL3,AP4)

これらの式を直接エクセルにコピー/ペーストして、またそれを下にコピー/ペーストしてくださいね。最初は５０行下まででも構いませんよ。その方がテストがし易いかもしれませんね。

まだＡＪ列からＡＮ列まで式がはいっていないので０のままかもしれませんが、今はそれで問題はないです。

つづく

その5.トレーリングストップ+売買サイン

つづき

検証シート全体図（４／６の記事）２番目を参照してください。

今から書く式の説明は既に売買指示シート作成で書いていますので、そちらを見てください。

｛セルＡＢ２｝・・・保有期間　　　　　（この保有期間は積極型２）

｛セルＡＢ３｝・・・=IF(OR($AA3=1,$AA3=2),AB4+1,0)

｛セルＡＣ１｝・・・=$ＡＹ$6　　　　　　　｛セルＡＣ２｝・・・ストップ値

｛セルＡＣ１｝・・・=IF(AA3=1,IF(AC4>TRUNC(U3-U3*$AY$6),IF(AC4="",TRUNC(U3-U3*$AY$6),AC4),TRUNC(U3-U3*$AY$6)),"")

｛セルＡＤ２｝・・・ストップ

｛セルＡＤ３｝・・・=IF(AND(AA3=1,E3<=AC3),"ストップ","")

｛セルＡＥ２｝・・・売買サイン　　　　（これがＰｒｏｇｒｅ02の売買サインです。）

｛セルＡＥ２｝・・・=IF(AD3="ストップ", IF(AD4="",4,0), IF(AND(AA3=1,OR(AE4=0,AE4=4)),3,IF(AA3=2,IF(OR(AE4=4,AE4=0),0,2),IF(AA3=0,0,IF(AA3=3,3,1)))))

｛セルＡF２｝・・・保有期間P

｛セルＡF３｝・・・=IF(OR($AE3=1,$AE3=2,$AE3=4),AF4+1,0)

｛セルＡＧ２｝・・・建値P

｛セルＡＧ３｝・・・=IF($AE3=3,$E3,IF(OR($AE3=1,$AE3=4),AG4,IF($AE3=2,AG4,0)))

｛セルＡＨ２｝・・・落値P

｛セルＡＨ３｝・・・=IF(OR($AE3=2,$AE3=4),$E3,"")

｛セルＡＩ２｝・・・損益P

｛セルＡＩ３｝・・・=IF(AH3="","",AH3-AG3)

　式ばかりで無味乾燥ですよネ。今日はこれぐらいにしておきます。ここまでは売買指示シートと共通している部分です。次回からが検証シートようの計算式に入ります。

　式の説明も書かねばならないので、ゆっくりと書いていきます。間違いを見つけた方は教えてくださいネ。

つづく

その4．建値・落ち値・損益

　今回入れる式は昨日に入れた積極型２フラッグに基づくもので、検証には直接関係ありません。しかし、ストップ無しでどのような結果になるか、トレーリングストップの有無の結果を比較することが出来ますし、後々なにかに使えると思います。

　それでは入れて行きます。

｛セルＷ２｝・・・建値

｛セルＷ３｝・・・=IF($AA3=3,$E3,IF(OR($AA3=1,$AA3=2),W4,""))

｛セルＸ２｝・・・落ち値　　　　｛セルＸ３｝・・・=IF($AA3=2,$E3,"")

｛セルＹ２｝・・・損益　　　　　｛セルＹ３｝・・・=IF(X3="","",X3-W3)

　　　　　　　　　　　　　　　************

　この建値、落ち値には問題があります。　システムのようにサインが出てから実際にこのようなところで買えるのか？売れるのか？

　売買のサインにおいてストップの基準はその日の高値、ゴーの基準はその日の安値。一方、建値、落ち値の執行はその日の終値、何か矛盾しているようです。実際の取引では前日のサインを元に寄り付きで注文を出すか、あらかじめどの値を超えればサインが変わるか把握しておいて、逆指値で注文を出しておくか、でしょうね。

　ただ完全自動ではないので、実際の取引はサインが出てから１テンポも２テンポもタイミングがずれます。今後の検証結果と実際の取引の結果との間に違いが出てきますが、そのことも頭に入れておいてください。

　例えば２月末の暴落ですが、暴落前に売りのサインが出ていました。しかし、それは２月２７日の引けのことです。サインに気づき，翌２月２８日の寄りつきで売れば、とんでもない安値で売ってしまうことになります。ざら場で取引できるのか、寄りつきか，後場寄りつきか，引けで取引できるのか、それは人それどれの状況に依って変わります。システム上はどこか一つに決めなければなりません。とうシステムはこれを終値と決めております。

　１０手先を読めとは言いません。持っている株なら、絶えず売りのサインがどのポイントで出るか、１手先ぐらいは読んで行動したいものです。その様な行動をとれば，また準備（心の準備）が出来ていれば、２月２７日の引け３０分前に売ることも可能になります。

　つづく

その3.売買サイン（積極型2フラッグ）

　いよいよ，売買フラッグを入れます。とうシステムの心臓部分です。

｛セルＡＡ１｝・・・積極型２　　　　　｛セルＡＡ２｝・・・フラッグ

｛セルＡＡ３｝・・・=IF(OR(AND($N4="*",$N3=""),AND($P4="",$P3="*")),IF(OR(AA4=1,AA4=3),1,3),IF(OR(AND($P4="*",$P3=""),AND($N4="",$N3="*")),IF(OR(AA4=0,AA4=2),0,2),IF(AA4=2,0,IF(AA4=3,1,AA4))))

となります。

　また、これをＥｘｐｅｃｔ01の｛ＡＥ列｝にコピーすれば、Inspire03になります。その場合ＡＡを全てＡＥに変えてください。（いつものミスの原因）（いったん上の条件式を｛セルＡＡ３｝にコピーしそれを｛セルＡＥ３｝にコピーすれば良いかもしれません）

　　　　　　　　　　　　　　　　　*************

　式の説明

しかし複雑である。自分が作ったのに理解に苦しむ。式を分解して説明してみます。

まず簡単にＥｘｃｅｌのＩＦ関数について

＝ＩＦ（条件、けっか1、けっか２）

ＥｘｃｅｌのＩＦ関数は基本的には上のようになります。条件が真ならけっか1、条件が偽ならけっか２となります。

この式をけっか1、けっか２の２つに分けて説明します。

　　　　　　　　　　　　　　　*************

OR(AND($N4="*",$N3=""),AND($P4="",$P3="*")),IF(OR(AA4=1,AA4=3),1,3),

赤の部分が条件、茶色の部分がけっか1

それでもまだ複雑です。ツリーを書いていて、また簡単に出きることが分かりました、公開するのは修正した式ですが、今できるだけ簡素化しようと努力しています。茶色の部分もＯＲでまとめられるはずなのにそれをすればエラーが出る。これでも間違いではないのでここはこのままにしておきます。（緑の部分けっか２ は出来ているのに，不可解）

分かりましたＯＲでまとめてから括弧を１つ外し忘れていました。長い式になると括弧が多くなって頭が混乱してしまいます。

上の式は修正後のスッキリした式です。綺麗な式になったと思います。（自我自賛）

　　　　　　　　　　　　　　　　**********

　IF(OR(AND($P4="*",$P3=""),AND($N4="",$N3="*")),IF(OR(AA4=0,AA4=2),0,2),IF(AA4=2,0,IF(AA4=3,1,AA4)))

良く見るとけっか２は上で説明した式と同じ構成になっています。

青の部分が条件、緑の部分がけっかです。ここまで来ると説明がつくのは早いです。上のツリーを使えば早く出来ます。

つづく

次回は　　建値・落ち値です。

　　これには色々な問題を含んでいます。ブログを書きもって色々と考えていきます。

その2．元になる数値の式

　全体図(4月６日の記事）の１番目の図を参照してください。

　今回は各パラメータと元になる数値、の箇所を作ります。Ｅｘｐｅｃｔ01と内容は一緒です。違うのは各式の変数をその１で作ったパラメータ（セル）に置き換えている点です。

　Ｈ列、Ｉ列はＥｘｐｅｃｔ01からコピーしてください。

｛セルＪ２｝・・・＝$ＡＹ$１１

｛セルＪ３｝・・・=AVERAGE(I3:OFFSET(I3, $AY$11-1, 0))

｛セルＫ２｝・・・＝$ＡＹ$７　　　　　　｛セルＫ３｝・・・=J3*$AY$7

｛セルＬ２｝・・・＝$ＡＹ$８　　　　　　｛セルＬ３｝・・・=J3*$AY$8

｛Ｍ列｝から｛Ｐ列｝はＥｘｐｅｃｔ01からコピーしてください。

｛セルＱ１｝・・・＝$ＡＹ$９

｛セルＱ３｝・・・=MAX($C3:OFFSET($C3,$AY$9-1,0))

｛セルＳ１｝・・・＝$ＡＹ$１０

｛セルＳ３｝・・・=MIN($D3:OFFSET($D3,$AY$10-1,0))

｛セルＵ１｝・・・＝$ＡＹ$１３

｛セルＳ３｝・・・'=MAX($C3:OFFSET($C3,$AY$13-1,0))

ここまでは簡単ですよネ。

　次回は　　　　いよいよＰｒｏｇｒｅ02（積極型２）の売買サインの条件式を書きます。見逃さないでくださいネ。

　　　　　　ちなみにＥｘｐｅｃｔ01の売買サインは（積極型１）です。

その1．パラメータの数値を入れるセル

　全体図の３番目を参照しながら作業を進めてください。（これからの作業は全体図を参照しながら行っていきます。）

｛セルＡＸ３｝・・・初期資金　　　　　　　　　｛セルＡＹ３｝・・・1000000

｛セルＡＸ４｝・・・単位株数　　　　　　　　　｛セルＡＹ４｝・・・1000

｛セルＡＸ５｝・・・手数料　　　　　　　　　　｛セルＡＹ５｝・・・1000

｛セルＡＸ６｝・・・ストップ率　　　　　　　　　｛セルＡＹ6｝・・・4％

｛セルＡＸ７｝・・・ボラ倍率　その1　　　　　｛セルＡＹ７｝・・・3

｛セルＡＸ８｝・・・ボラ倍率　その２　　　　　｛セルＡＹ８｝・・・２．５

｛セルＡＸ９｝・・・何日間最大その1　　　　　｛セルＡＹ９｝・・・１８

｛セルＡＸ１０｝・・・何日間最小その２　　　　｛セルＡＹ１０｝・・・７

｛セルＡＸ１１｝・・・ＡＴＲ平均日数　　　　　　｛セルＡＹ１１｝・・・１９

｛セルＡＸ１２｝・・・リスク率　　　　　　　　　　｛セルＡＹ１２｝・・・３．６％

｛セルＡＸ１３｝・・・何日間最大その2　　　　｛セルＡＹ１３｝・・・３

パラメータの項目は以上です。ＡＹ列のセルの書式を各自で調整してください。

この下の検証結果の欄は今入れてもエラー表示になりますので後程、随時入れていきます。

つづく

検証シート全体図

今までも部分的に検証シートならびに検証作業を見ていただいたのですが。

　今日は検証シートの全体を見てもらおうと思います。

　これが１枚のシートになっていて（Ｅｘｐｅｃｔ０１，Ｐｒｏｇｒｅ02，Ｉｎｓｐｉｒｅ03の３枚）、これにデータ取得用のシート、検証結果記録用のシートで1つのブックになっています。

　これから上の2番目の部分、損益曲線や検証に必要な数値を出すための計算式を書いていきます。（どの式から書いたらよいのだろうか悩む・・・一晩考えれば何とかなるだろう、　　一休み）

　ところが昨日売買サインのミスに気づきました。（訂正済み）ここでしかりと式の列位置、セル位置を決めておかないとまた同じミスをしてしまう。上の検証シートはＰｒｏｇｒｅ02で、Ｅｘｐｅｃｔ01と配列が少し違います。なんとかして、どれかに統一しなければブログと僕のシートと違いが出来同じようなミスが起こる可能性が出てきます。悩む・・・・

　ここで各列の式を全部一覧にしてお見せするのが１番楽なのですが。ブログの構成上まだそれは出来ません。この一連の記事を書き終えた段階で、今までの式を全部一覧にしたいと思います。ですから今は少しのミスには目をつぶっていただいて先に進めていきます。

　良く考えてみますと，検証ブックは売買指示シートとは別に作らなければなりませんから。Ｐｒｏｇｒｅ02に統一して新たに書いていくことにします。大サービスでＰｒｏｇｒｅ02の売買サインも書きます。今後、完全にＥｘｐｅｃｔ01からＰｒｏｇｒｅ02に移行していきます。

　その方がブログも読みやすくなるであろうし、私も記事が書きやすいし、性も無いミスもなくなるし、実戦に集中できるし、良い事ばかりであります。

つづく